ภาษาโปรแกรม PLC ตาม IEC 61131-3: LD FBD ST SFC และ IL — โปรแกรมเดียวกันในหลายภาษา ชนิดข้อมูล และการเลือกใช้

โจทย์เดียว ห้าภาษา พื้นฐาน

อินพุต: STOP (NC) START · เอาต์พุต: แตร (Horn) สายพาน (Conveyor) · กด START แล้วแตรดัง 5 s จากนั้นสายพานเดิน กด STOP หยุดทั้งหมด

Ladder Diagram (LD)

  I0.0(STOP)   I0.1(START)                       M0.0
──┤ ├────────┬──┤ ├──────┬───────────────────────( )──   สั่งเดิน (ล็อกตัวเอง)
             │  M0.0     │
             └──┤ ├──────┘
  M0.0                       ┌─TON T1──┐
──┤ ├────────────────────────┤IN      Q├───────────      นับ 5 s
                      T#5s ──┤PT    ET├
  M0.0        T1                                  Q0.1
──┤ ├────────┤/├────────────────────────────────( )──   แตร
  T1                                              Q0.0
──┤ ├───────────────────────────────────────────( )──   สายพาน

Function Block Diagram (FBD)

          ┌──────┐
 START ───┤  ≥1  │      ┌──────┐
 Run ─────┤      ├──────┤  &   ├──── Run
          └──────┘ STOP─┤      │
                        └──────┘
          ┌─TON───┐                  ┌──────┐
 Run ─────┤IN    Q├──── T1.Q ───────┤  &   │
  T#5s ───┤PT  ET├     Run ─────────┤      ├──── Horn
          └───────┘    T1.Q ──o─────┤      │      (o = กลับค่า)
                                     └──────┘
 T1.Q ───────────────────────────────────────── Conveyor

Structured Text (ST)

VAR
    Run      : BOOL;
    T1       : TON;
END_VAR

Run := (PB_Start OR Run) AND PB_Stop_NC;      // ล็อกตัวเอง
T1(IN := Run, PT := T#5S);                       // เรียกอินสแตนซ์ไทเมอร์ทุกสแกน
Horn     := Run AND NOT T1.Q;
Conveyor := T1.Q;

Sequential Function Chart (SFC)

  ╔══════╗
  ║ 0 รอ ║
  ╚══╤═══╝
   ──┼── START
  ┌──┴───┐   ┌────────────┐
  │1 เตือน├───┤ N  Horn    │
  └──┬───┘   └────────────┘
   ──┼── Step1.T >= T#5s
  ┌──┴───┐   ┌────────────┐
  │2 เดิน ├───┤ N Conveyor │
  └──┬───┘   └────────────┘
   ──┼── NOT PB_Stop_NC
     └──────► กลับขั้น 0

Instruction List (IL) — ภาษาที่ถูกยกเลิก

LD   PB_Start
OR   Run
AND  PB_Stop_NC
ST   Run

IL คล้ายภาษาแอสเซมบลี ถูกตัดออกจาก IEC 61131-3 ฉบับที่ 3 (2013) แต่ยังพบในโปรแกรมเก่า (Siemens STL, Mitsubishi List)

ชนิดข้อมูลและค่าคงที่ กลาง

วิธีหลีกเลี่ยง: แปลงเป็น REAL ก่อนคำนวณ (INT_TO_REAL) หรือใช้ DINT และคูณก่อนหาร — ตัวอย่างการสเกลอยู่ใน อนาล็อก · PID

สร้างฟังก์ชันบล็อกมอเตอร์ใช้ซ้ำ ขั้นสูง

โรงงานที่มีมอเตอร์ 50 ตัว ไม่ควรเขียนวงจรล็อกตัวเอง ตรวจป้อนกลับ และนับชั่วโมงซ้ำ 50 ครั้ง สร้าง FB หนึ่งตัวแล้วเรียก 50 อินสแตนซ์

FUNCTION_BLOCK FB_Motor
VAR_INPUT  Start, Stop_NC, OL_NC, Feedback : BOOL; FbTime : TIME := T#2S; END_VAR
VAR_OUTPUT Run, Fault : BOOL; Hours : REAL; END_VAR
VAR Cmd : BOOL; TFb : TON; THr : TON; END_VAR

Cmd := (Start OR Cmd) AND Stop_NC AND OL_NC AND NOT Fault;
TFb(IN := Cmd XOR Feedback, PT := FbTime);   // สั่งแล้วไม่มีป้อนกลับ หรือไม่สั่งแต่มีป้อนกลับ
IF TFb.Q THEN Fault := TRUE; END_IF          // รีเซ็ต Fault จาก HMI
Run := Cmd;
THr(IN := Feedback AND NOT THr.Q, PT := T#36S);  // พัลส์ทุก 0.01 ชม.
IF THr.Q THEN Hours := Hours + 0.01; END_IF
END_FUNCTION_BLOCK

เลือกภาษาให้เหมาะกับงาน